[sc-users] SC AU

[0001]

there's also a basic tutorial in the link to the supercollider  
symposium materials at http://supercolliderau.sourceforge.net
setting the synthdef dir should not be needed.

...

gerard


El 27/12/2006, a las 19:20, blackrain escribió:

> you will need the first operating mode of the plug as described in the
> SCAU's site
> ( at http://supercolliderau.sourceforge.net/ )
> - Only Server. Simply manages the scsynth process. Needs to be
> controlled via OSC.
>
> then:
> 1 - place the SCAU plugin in ~/Library/Audio/Plug-Ins/Components
> 2 - launch logic, live or whichever is your AU host app.
> 3 - instantiate the plug in an audio track/audio (or fx) return
> 4 - launch supercollider if not already running
> 5 - follow this:
>
> //create a new server object and make it our default server
> //port number (9989) is the default for SCAU - this number will  
> change as
> //you create other scau plugs - look in the plugin's UI.
> Server.default = s = Server.new("sc au",NetAddr("127.0.0.1", 9989));
>
> //set the place where the server stores its defs to the synthdefs
> directory in the plug
> (
> SynthDef.synthDefDir_("~/Library/Audio/Plug-Ins/Components/\
> SuperColliderAU.component/Contents/Resources/ 
> synthdefs".standardizePath);
> )
> // set the latency we want
> s.latency = 0.05;
>
> // initialize the groups tree
> s.initTree;
>
> //we may use notifications from the server so ask for them
> s.notify;
>
> //finally make a window for our new server - the AU plug
> s.makeWindow;
>
> 6 - from here on, scau works just like the default local server does
>
> //send a def to scau
> (
> SynthDef("sine", { arg out=0, gate=1.0;
> 	var osc, freq;
> 	freq = MouseY.kr(20e3,20,1);
> 	osc = SinOsc.ar(freq, 0, 0.1) * EnvGen.kr(Env.asr, gate,  
> doneAction:2);
> 	Out.ar(out, Pan2.ar(osc,MouseX.kr(-1,1),1));
> }).send(s);
> )
>
> //launch and control a synth - osc style
> s.sendMsg("/s_new", "sine", x = s.nextNodeID, 1, 1);
> s.sendMsg("/n_set", x, \gate, 0.0)
>
> s.sendMsg("/n_free", x);
>
> //a func
> z = { SinOsc.ar(110.0,0,0.1) ! 2 }.play
> z.release
>
> (
> SynthDef(\click, { arg out=0, freq=1200.0, len=0.1, amp=0.1, pos=0;
> 	Out.ar(out, Pan2.ar(
> 		FSinOsc.ar(freq,0, Line.kr(amp, 0, len, doneAction: 2)), pos));
> }).send(s);
> )
>
> (
> SynthDef(\clickm, { arg out = 0, freq=1200.0, len=0.1, amp=0.1;
> 	Out.ar(out, FSinOsc.ar(freq,0, Line.kr(amp, 0, len, doneAction: 2)));
> }).send(s);
> )
>
> s.sendMsg(\s_new, \click, 2000, 0, 1, \amp, 1.0);
>
> (
> t = Task ({
> 	loop({
> 		s.sendMsg("/s_new", "click", x = s.nextNodeID, 0, 1, \amp, 1.0);
> 		1.0.wait;
> 	});
> });
> )
> t.play
> t.stop
>
> etc...
> hope this helps some.
>
> cheers,
>
> x
>
>
> On 12/27/06, elec musi <elec.musi at gmail.com> wrote:
>> What someone be so kind as to post a basic tutorial
>> on the SC AU plugin. Where do I put the file. How do I get
>> a FSinOsc to play through it into a Logic Audio track.
>> Thanks,
>> Elecs
>> _______________________________________________
>> sc-users mailing list
>> sc-users at create.ucsb.edu
>> http://www.create.ucsb.edu/mailman/listinfo/sc-users
>>
> _______________________________________________
> sc-users mailing list
> sc-users at create.ucsb.edu
> http://www.create.ucsb.edu/mailman/listinfo/sc-users